***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 16, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5476AL-AU   D   G   S
*****param & model definition***
.model  dmos  nmos( 
+    l = 1e-6		  w = 1e-6			level = 3
+  vto = 2.2		       kp = 40.25)
.model  dds   d( 
+   is = 5.123e-11	  n = 1.084			   rs = 1.203e-2
+   eg = 1.000	     trs1 = -1.00e-3)
.model  dbody d( 
+   is = 5.123e-11	  n = 1.084			   rs = 1.203e-2
+  cjo = 5.691e-10	  m = 6.199e-1		   vj = 8.005e-1
+   bv = 110	      ibv = 250e-6		 tbv1 = 7.698e-4			tt = 25n
+trs1 = -1.00e-3)          
.model  inter  nmos( 
+  vto = 0			 kp = 10			level = 1)
.model  dgd    d(
+  cjo = 7.099-10		  m = 6.357e-1		   vj = 5.336e-1)
.param 
+  cgs = 2.079e-9	cgd = 6.832e-10
+   rd = 6.801e-3	      ra  = 3.805e-3			  trd = 2.670e-2 
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   ic = 0
egv	  2t  3   table   {v(1t, S)} 
+((0   , 0   ),
+ (0.5 , 0.5), 
+ (1   , 1   ),
+ (1.5 , 1.5 ),
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (2.75, 2.75),
+ (3   , 3), 
+ (3.5, 3.5),
+ (4, 3.75),
+ (4.5 , 4.45),
+ (5   , 4.49),
+ (6   , 4.65),
+ (8   , 4.9),
+ (10  ,4.95),   
+ (20  , 5.2),
+ (22  , 5.2))
egt	  1  2t   value = {5.987e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
